鐵之狂傲

標題: 自製系統5-複合按鈕作標題畫面 [列印本頁]

作者: 發條人形紅舞鞋 時間: 08-3-1 04:03
標題: 自製系統5-複合按鈕作標題畫面

機翻自複合ボタン

閱讀建議
這篇其實和LEVEL 7 LSP的混沌宇宙（3）用EXBTN升級你的系統畫面內容是一樣的，
基於互為參考的意義一併附上。

本回使用
exbtn 複合按鈕的狀態設置。可以附加音效，也可以控制文字列設置滑鼠懸停時的一系列sp變化
exbtn_d 定義當遊標不在任何按鈕上時，畫面的顯示。
控制文字列 P=顯示SP。C=隱藏SP。M=移動SP。S=播放音效。

前言
複合按鈕NScripter日文版有示範的樣品
不過，樣品有地方並沒有解說到，
因為複合按鈕經常會使用到，所以特別解說一下。

NScripter有幾個按鈕命令，
不過，其中表現力最高的是複合按鈕。
在此採用複合按鈕製作標題畫面。

首先，準備按鈕用圖和音效檔。
(音效請自己抓)

[ 本文最後由發條人形紅舞鞋於 08-3-3 02:09 AM 編輯 ]

[ 本文章最後由發條人形紅舞鞋於 08-7-3 14:03 編輯 ]

開始遊戲

繼續遊戲

離開遊戲

滑鼠指向

作者: 發條人形紅舞鞋 時間: 08-3-1 04:05
標題: 實裝前測試1
畫面效果程式碼

;mode800
*define
transmode alpha
game
*start
bg #FFFFFF,10,1000
lsph 1,":a/2,0,3;img\newgame.jpg",40,360
lsph 2,":a/2,0,3;img\continue.jpg",40,400
lsph 3,":a/2,0,3;img\end.jpg",40,440
vsp 1,1
vsp 2,1
vsp 3,1
print 10,500
click
end

複製代碼

畫面效果預覽

這樣呈現應該就OK了吧，
接下來要把圖像按鈕化。
下面是按鈕的基本形。

[ 本文最後由發條人形紅舞鞋於 08-3-3 01:13 AM 編輯 ]

作者: 發條人形紅舞鞋 時間: 08-3-1 04:07
標題: 實裝前測試2
基本按鈕程式碼

;mode800
*define
transmode alpha
useescspc;允許使用esc鍵和空白鍵，esc鍵返回值-10，空白鍵返回值-11
game
*start
bg #FFFFFF,10,1000
lsph 1,":a/2,0,3;img\newgame.jpg",40,360
lsph 2,":a/2,0,3;img\continue.jpg",40,400
lsph 3,":a/2,0,3;img\end.jpg",40,440
btndef "" ;清除按鈕定義
exbtn_d "P1P2P3" ;游標不在任何按鈕上
exbtn 1,1,"P1,1P2P3" ;游標在exbtn1上
exbtn 2,2,"P1P2,1P3" ;游標在exbtn2上
exbtn 3,3,"P1P2P3,1" ;游標在exbtn3上
btnwait %0 ;等待點擊並根據點擊位置給數位變數0賦值。
if %0 = -10 end ;數位變數0等於-10 遊戲結束
%0 ;顯示數位變數0的值
click
end

複製代碼

基本按鈕預覽

exbtn SP號碼,按鈕號碼,控制文字列
照著格式寫也不是那麼困難對吧？
控制文字列，有「P」「C」「M」「S」四個組合。

繼續增修以下腳本。
游標移到按鈕的時候要有音效，
決定的時候也要有音效。

[ 本文最後由發條人形紅舞鞋於 08-3-3 01:53 AM 編輯 ]

作者: 發條人形紅舞鞋 時間: 08-3-1 04:08
標題: 最終標題
最終標題畫面程式碼

;mode800
*define
transmode alpha
useescspc;允許使用esc鍵和空白鍵，esc鍵返回值-10，空白鍵返回值-11
game
*start
bg #FFFFFF,10,1000
lsph 0,":l/10,30,1;img\bar.jpg",0,0
lsph 1,":a/2,0,3;img\newgame.jpg",40,360
lsph 2,":a/2,0,3;img\continue.jpg",40,400
lsph 3,":a/2,0,3;img\end.jpg",40,440
btndef "" ;清除按鈕定義
exbtn_d "P0P1P2P3M0,0,610";游標不在任何按鈕上
exbtn 1,1,"P1,1P2P3S1,(wav\se001.wav)M0,44,396";游標在exbtn1上
exbtn 2,2,"P1P2,1P3S2,(wav\se001.wav)M0,44,436";游標在exbtn2上
exbtn 3,3,"P1P2P3,1S3,(wav\se001.wav)M0,44,476" ;游標在exbtn3上
*btn_loop
btnwait %0 ;等待點擊並根據點擊位置給數位變數0賦值。
if %0 = 1 gosub *title_end:goto *new_game ;數位變數0等於1 跳到標籤title_end 再跳往標籤new_game
if %0 = 2 gosub *title_end:goto *continue ;數位變數0等於2 跳到標籤title_end 再跳往標籤continue
if %0 = 3 gosub *title_end:end ;數位變數0等於3 跳到標籤title_end 再結束
if %0 = -10 end
goto *btn_loop
*title_end
wave "wav\se002.wav"
csp -1
print 10,500
wait 1000
return
*new_game
遊戲開始\
end
*continue
繼續遊戲\
end

複製代碼

最終標題畫面預覽
展示效果請看附件
音效素材來源
Free音素材「音楽室」または、otosozai.com、ongakusitu
http://www.otosozai.com

P SP號碼,影格(禎號)
顯示SP。無指定影格的情況，影格0默認顯示。
C SP號碼
隱藏SP。
M SP號碼,X絕對坐標,Y絕對坐標
移動SP
S音軌,(音效檔名+路徑)
播放音效。

"P1,1P2P3S1,(wav\se001.wav)M0,44,396"
這個表示
P1,1 = SP1影格1
P2 = SP2
P3 = SP3
S1,(wav\se001.wav) = 播放音軌1指定的檔案
M0,44,396 = SP0X移動到44，Y到396

請利用上述的項目製作控制文字列。
以上。

[ 本文最後由發條人形紅舞鞋於 08-3-3 02:08 AM 編輯 ]

標題範例.rar

289.41 KB, 下載次數: 470, 下載積分: 鐵幣 -5 元

範例檔

作者: 偽．奇才 時間: 08-8-9 20:57
最近爬文才發現發條有發教學文章~~發條對不起...我之前都沒發現~~>"<

exbtn做出來的畫面真的是很精緻呢
因為看中文畫不完全手冊...裡面沒寫到範例，所以完全不知道怎麼用
到現在還是只會spbtn~~囧||
所以想問一下下面的程式碼...囧

主要就是下面這一行不懂
exbtn_d "P0P1P2P3M0,0,610";游標不在任何按鈕上
首先是游標不在畫面上顯示的部分
P0P1P2P3M0 <-- 顯示片SP0,顯示圖片SP1,顯示圖片SP2,顯示圖片SP3,移動圖片SP0
我想知道這部分為什麼是這樣寫呢？還是這只是定義總共有幾張ＳＰ圖片阿@@?

如果是這樣的話...如果有第4張圖片是不是就變成要這樣寫了呢?
exbtn_d "P0P1P2P3P4M0,0,610"
exbtn 1,1,"P1,1P2P3P4S1,(wav\se001.wav)M0,44,396"
exbtn 2,2,"P1P2,1P3P4S2,(wav\se002.wav)M0,44,436"
exbtn 3,3,"P1P2P3,P41S3,(wav\se003.wav)M0,44,476"
exbtn 4,4,"P1P2P3P4,1S4,(wav\se004.wav)M0,44,525"

另外...不知道移動特效能不能設定成不同張圖片的呢?
像是：
假設現在多了一張lsph 5的圖片
exbtn 1,1,"P1,1P2P3P4S1,(wav\se001.wav)M0,44,396"
exbtn 2,2,"P1P2,1P3P4S2,(wav\se002.wav)M5,44,436"
exbtn 3,3,"P1P2P3,P41S3,(wav\se003.wav)M5,44,476"
exbtn 4,4,"P1P2P3P4,1S4,(wav\se004.wav)M0,44,525"

部分是移動SP0、SP5
如果想做到這樣的效果...可以嗎@@?

歡迎光臨鐵之狂傲 (https://gamez.com.tw/)